#!/usr/bin/perl -w

=pod

=head1 NAME

tv_grab_za_etv - Grab TV listings for South Africa, from etv.co.za.

=head1 SYNOPSIS

tv_grab_za_etv --help

tv_grab_za_etv [--config-file FILE] --configure [--gui OPTION]

tv_grab_za_etv [--config-file FILE] [--output FILE] [--days N]
           [--offset N] [--quiet] [--cacheage N]

tv_grab_za_etv --list-channels

=head1 DESCRIPTION

Output TV listings for the e-TV channel available in South Africa.
The data comes from www.etv.co.za which is owned by the broadcaster.  
The grabber relies on parsing HTML so it might stop working at any time.

First run B<tv_grab_za_etv --configure> to choose, which channels you want
to download. Then running B<tv_grab_za_etv> with no arguments will output
listings in XML format to standard output.

B<--configure> Prompt for which channels,
and write the configuration file.

B<--config-file FILE> Set the name of the configuration file, the
default is B<~/.xmltv/tv_grab_za_etv.conf>.  This is the file written by
B<--configure> and read when grabbing.

B<--gui OPTION> Use this option to enable a graphical interface to be used.
OPTION may be 'Tk', or left blank for the best available choice.
Additional allowed values of OPTION are 'Term' for normal terminal output
(default) and 'TermNoProgressBar' to disable the use of XMLTV::ProgressBar.

B<--output FILE> write to FILE rather than standard output.

B<--days N> grab N days.  The default is ten.

B<--offset N> start N days in the future.  The default is to start
from today.

B<--quiet> suppress the progress messages normally written to standard
error.

B<--cacheage N> will try and cache downloads, and reuse them if the file is
younger than N days old.  The default is to cache downloads for 1 day.

B<--list-channels> write output giving <channel> elements for every
channel available (ignoring the config file), but no programmes.

B<--help> print a help message and exit.

=head1 SEE ALSO

L<xmltv(5)>.

=head1 AUTHOR

Norman Rasmussen, norman@rasmussen.org.  
Based on tv_grab_fi by Matti Airas, mairas@iki.fi.  
tv_grab_fi originally based on tv_grab_sn by Stefan G:orling.

=head1 BUGS

The data source is not formatted particularly consistently so we have to
guess about what data goes where sometimes.  The last programme each day
does not get a stop date.

=cut

######################################################################
# initializations

use strict;
use XMLTV::Version '$Id: tv_grab_za_etv,v 1.01 2004/12/21 02:19:39 normanr Exp $ ';
use Getopt::Long;
use Date::Manip;
use HTML::TreeBuilder;
use HTML::Entities; # parse entities
use IO::File;

use XMLTV;
use XMLTV::Memoize;
use XMLTV::ProgressBar;
use XMLTV::Ask;
use XMLTV::Config_file;
use XMLTV::Get_nice;
use XMLTV::Mode;
use XMLTV::Date;
use XMLTV::Usage <<END
$0: get South African television listings from www.etv.co.za in XMLTV format
To configure: $0 --configure [--config-file FILE]
To grab listings: $0 [--config-file FILE] [--output FILE] [--days N]
        [--offset N] [--quiet] [--cacheage N]
To list channels: $0 --list-channels
END
  ;

# Attributes of the root element in output.
my $HEAD = { 'source-info-url' => 'http://www.etv.co.za/',
	     'source-data-url'     => 'http://www.etv.co.za/schedule.php',
	     'generator-info-name' => 'XMLTV',
	     'generator-info-url'  => 'http://membled.com/work/apps/xmltv/',
	   };

# default language
my $LANG="en-ZA";

# Global channel data.
our @ch_all;


######################################################################
# get options

# Get options, including undocumented --cache option.
XMLTV::Memoize::check_argv('XMLTV::Get_nice::get_nice_aux');
my ($opt_days, $opt_offset, $opt_help, $opt_output, $opt_cacheage,
    $opt_configure, $opt_config_file, $opt_gui,
    $opt_quiet, $opt_list_channels);
$opt_days  = 10; # default
$opt_offset = 0; # default
$opt_cacheage = 1; # default
$opt_quiet  = 0; # default
GetOptions('days=i'    => \$opt_days,
	   'offset=i'      => \$opt_offset,
	   'cacheage=i'    => \$opt_cacheage,
	   'help'          => \$opt_help,
	   'configure'     => \$opt_configure,
	   'config-file=s' => \$opt_config_file,
       'gui:s'         => \$opt_gui,
	   'output=s'      => \$opt_output,
	   'quiet'         => \$opt_quiet,
	   'list-channels' => \$opt_list_channels,
	  )
  or usage(0);
die 'number of days must not be negative'
  if (defined $opt_days && $opt_days < 0);
usage(1) if $opt_help;

XMLTV::Ask::init($opt_gui);

my $mode = XMLTV::Mode::mode('grab', # default
			     $opt_configure => 'configure',
			     $opt_list_channels => 'list-channels',
			    );

# File that stores which channels to download.
my $config_file
  = XMLTV::Config_file::filename($opt_config_file, 'tv_grab_za_etv', $opt_quiet);

my @config_lines; # used only in grab mode
if ($mode eq 'configure') {
    XMLTV::Config_file::check_no_overwrite($config_file);
}
elsif ($mode eq 'grab') {
    @config_lines = XMLTV::Config_file::read_lines($config_file);
}
elsif ($mode eq 'list-channels') {
    # Config file not used.
}
else { die }

$XMLTV::Get_nice::get = \&cached_get;

# Whatever we are doing, we need the channels data.
my %channels = get_channels(); # sets @ch_all
my @channels;

######################################################################
# write configuration

if ($mode eq 'configure') {
    open(CONF, ">$config_file") or die "cannot write to $config_file: $!";

    # Ask about each channel.
    my @chs = sort {join('.', reverse split(/\./, $a)) cmp join('.', reverse split(/\./, $b))} keys %channels;
    my @names = map { $channels{$_} } @chs;
    my @qs = map { "add channel $_?" } @names;
    my @want = ask_many_boolean(1, @qs);
    foreach (@chs) {
	my $w = shift @want;
	warn("cannot read input, stopping channel questions"), last
	  if not defined $w;
	# No need to print to user - XMLTV::Ask is verbose enough.

	# Print a config line, but comment it out if channel not wanted.
	print CONF '#' if not $w;
	my $name = shift @names;
	print CONF "channel $_ $name\n";
	# TODO don't store display-name in config file.
    }

    close CONF or warn "cannot close $config_file: $!";
    say("Finished configuration.");

    exit();
}

# Not configuration, we must be writing something, either full
# listings or just channels.
#
die if $mode ne 'grab' and $mode ne 'list-channels';

# Options to be used for XMLTV::Writer.
my %w_args;
if (defined $opt_output) {
    my $fh = new IO::File(">$opt_output");
    die "cannot write to $opt_output: $!" if not defined $fh;
    $w_args{OUTPUT} = $fh;
}
#$w_args{encoding} = 'UTF-8';
$w_args{encoding} = 'ISO-8859-1';
my $writer = new XMLTV::Writer(%w_args);
$writer->start($HEAD);

if ($mode eq 'list-channels') {
    # Write channels mode.
    $writer->write_channel($_) foreach @ch_all;
    $writer->end();
    exit();
}

######################################################################
# We are producing full listings.
die if $mode ne 'grab';

# Read configuration.
my $line_num = 1;
foreach (@config_lines) {
    ++ $line_num;
    next if not defined;
    if (/^channel:?\s+(\S+)\s+([^\#]+)/) {
		my $ch_did = $1;
		my $ch_name = $2;
		$ch_name =~ s/\s*$//;
		push @channels, $ch_did;
		$channels{$ch_did} = $ch_name;
    }
    else {
		warn "$config_file:$line_num: bad line\n";
    }
}

######################################################################
# begin main program

# Assume the listings source uses CAT (see BUGS above).
my $now = DateCalc(parse_date('now'), "$opt_offset days");
die "No channels specified, run me with --configure\n"
  if not keys %channels;
my @to_get;

# the order in which we fetch the channels matters
foreach my $ch_did (@channels) {
    my $ch_name=$channels{$ch_did};
    my $ch_xid=$ch_did;
    $writer->write_channel({ id => $ch_xid,
			     'display-name' => [ [ $ch_name ] ] });
    my $day=UnixDate($now,'%Q');
    for (my $i=0;$i<$opt_days;$i++) {
		push @to_get, [ $day, $ch_xid, $ch_did ];
		#for each day
		$day=nextday($day); die if not defined $day;
    }
}

# This progress bar is for both downloading and parsing.  Maybe
# they could be separate stages.
#
my $bar = new XMLTV::ProgressBar('getting listings', scalar @to_get)
  if not $opt_quiet;
foreach (@to_get) {
    foreach (process_table($_->[0], $_->[1], $_->[2])) {
		$writer->write_programme($_);
    }
    update $bar if not $opt_quiet;
}
$bar->finish() if not $opt_quiet;
$writer->end();

######################################################################
# subroutine definitions

# Use Log::TraceMessages if installed.
BEGIN {
    eval { require Log::TraceMessages };
    if ($@) {
	*t = sub {};
	*d = sub { '' };
    }
    else {
	*t = \&Log::TraceMessages::t;
	*d = \&Log::TraceMessages::d;
	Log::TraceMessages::check_argv();
    }
}

my $warned_bad_chars;
sub tidy( $ ) {
    for (my $tmp = shift) {
	tr/\t\205/ /d;
	s/&\#8230;/.../g;
	if (s/([^\012\015\040-\176\240-\377]+)//g) {
	    warn "removing bad characters: '$1'"
	      unless $warned_bad_chars++;
	}
	return $_;
    }
}

####
# process_table: fetch a URL and process it
#
# arguments:
#    Date::Manip object giving the day to grab
#    xmltv id of channel
#    etv id of channel
#
# returns: list of programme hashes to write
#
sub process_table {
    my ($date, $ch_xmltv_id, $ch_etv_id) = @_;

    my $today = UnixDate($date, '%s');
    my $url = "http://www.etv.co.za/schedule.php?tomorrow=$today&want_tomorrow=1";
    t "getting URL: $url";
    my $data=tidy(get_nice($url));
    if (not defined $data) {
		die "could not fetch $url, aborting\n";
    }
    local $SIG{__WARN__} = sub {
		warn "$url: $_[0]";
    };

    my @program_data = get_program_data($data);
    my $bump_start_day=0;

    my @r;
	while (@program_data) {
		my $cur = shift @program_data;
		my $next = shift @program_data;
		unshift @program_data,$next if $next;
		push @r, make_programme_hash($date, $ch_xmltv_id, $ch_etv_id, $cur, $next);
		if (!$bump_start_day && bump_start_day($cur,$next)) {
		    $bump_start_day=1;
		    $date = UnixDate(DateCalc($date,"+ 1 day"),'%Q');
		}
    }
    return @r;
}

sub make_programme_hash {
    my ($date, $ch_xmltv_id, $ch_etv_id, $cur, $next) = @_;

    my %prog;

    $prog{channel}=$ch_xmltv_id;
    $prog{title}=[ [ $cur->{title}, $LANG ] ];

    my $cur_time = $cur->{time};
    t 'raw time for programme: ' . d $cur_time;
    my $start=parse_date("$date $cur_time");
    t 'parse_date() returned: ' . d $start;
    $prog{start}=UnixDate($start, '%q') . " +0200";
    t 'set programme start time to: ' . d $prog{start};

    my $next_time = $next ? $next->{time} : undef;
    if (defined $next_time) {
		t '$cur_time=' . d $cur_time;
		t '$next_time=' . d $next_time;
		my $stop_date;
		if ($next_time lt $cur_time) {
		    # Must span midnight.  (Don't worry about start being
		    # summer time and stop being winter: we assume the site is
		    # sane enough to put them both in the same timezone and
		    # avoid looking like stop < start.)
		    #
		    t '$next_time appears sooner, must be next day';
		    $stop_date = nextday($date);
		}
		else {
		    $stop_date = $date;
		}
		t '$stop_date set to: ' . d $stop_date;
		my $stop = parse_date("$stop_date $next_time");
		t 'stop time in CAT: ' . d $stop;
		$prog{stop}=UnixDate($stop, '%q') . " +0200";
    }	

    # FIXME: parse description field further
    $prog{desc}=[ [ $cur->{desc}, $LANG ] ] if defined $cur->{desc};

    $prog{rating}=[ [ $cur->{rating} ] ] if defined $cur->{rating};

    $prog{date}=$cur->{year} if defined $cur->{year};
    
    $prog{"sub-title"}=[ [ $cur->{subtitle}, $LANG ] ] if defined $cur->{subtitle};

    $prog{category}=[ [ $cur->{category}, $LANG ] ] if defined $cur->{category};

    return \%prog;
}
sub bump_start_day {
    my ($cur,$next) = @_;
    if (!defined($next)) {
	return undef;
    }
    my $start = UnixDate($cur->{time},'%H:%M');
    my $stop = UnixDate($next->{time},'%H:%M');
    if (Date_Cmp($start,$stop)>0) {
	return 1;
    } else {
	return 0;
    }
}

# program data is split as follows:
# - p, with children b's with the time, title, rating, sub-title, year
#   in that order, but maybe some elements are missing
#   sometimes the title is a feature slot and the subtitle is the real title
#   sometimes the b are not split at all, but hopefully tidy() fixes that
# - p on the next row is the description. might be missing but if we're lucky 
#   there's a blank p after each program row, so we'll just see that.
#   otherwise it's lucky that all details are in b's so we 'see' nothing.
sub get_program_data {
    my $data = shift;
    my @data;

    # Subroutines to call on each element. 
    # This has been converted from a hash to an array
    #  because items need to be called in the correct order.
    my @keys = (
    	["year", \&get_year_str],
		["title", \&get_name_str],
		["rating", \&get_rating_str],
		["subtitle", \&get_subtitle_str],
	       );

    # parse the page to find each program
    while ($data =~ m{[^\n]+(\d\d:\d\d)(.*?)</p>.*?<p>(.*?)<}gis) {
		my %h;
    	my @b;
		$h{time}=$1;
		$h{desc}=get_desc_str($3);
		{
	    	my $blobs=$2;
	    	$blobs =~ s/\n/ /g;			# make newlines spaces
	    	$blobs =~ s!</b> <b>! !g;	# remove accidental re-boldness (in the middle of titles)
	    	$blobs =~ s/&\#160;/ /g;	# make non-braking spaces normal
	    	$blobs =~ s/<b>/    /g;		# convert b start and
	    	$blobs =~ s!</b>!    !g;	# b end tags into big spaces
	    	$blobs .= "    ";			# some secondary titles are right at the end, so add some padding
	    	while ($blobs =~ m{     \b(.+?)    }gis) {
	    		push @b, $1;
	    	}
    	}
		t 'doing elem: ' . $h{time} . ":" . join(',', @b);
	
		foreach my $sub (@keys) {
		    my @sub = $sub;
		    my $v = $sub->[1]->(\@b);
		    if (defined $v) {
				t "got a result from sub for $sub->[0]: $v";
				$h{$sub->[0]} = $v;
		    }
		}
		
		my $feature = $h{title};
	    if ((defined $h{subtitle}) && 
	    	(($feature =~ /^Feature\b/i) || 
	    	($feature =~ /\bFeature$/i) || 
	    	#($feature eq "Music Special") || # Music Special's are now treated as a full 'series', with many sub-title's
	    	($feature eq "Miniseries") || 
	    	($feature eq "Classic Movie Collection") || 
	    	($feature eq "Friday late") || 
	    	($feature eq "Sunday Movie - 11am") || 
	    	($feature =~ /\bMovie$/i))) {
	    	$h{title} = $h{subtitle};
	    	$h{subtitle} = undef;
	    	$h{category} = $feature;
	    }
	    
		t 'after running all subs, got data: ' . d \%h;
		push @data, \%h;
	    }
    t 'get_program_data() RETURNING ' . d \@data;
    return @data;
}
sub get_name_str {
    my ($blobs) = @_;
    $_ = shift @$blobs;
	s/^\s+//; s/\s+$//;
	return $_ if length($_);
	return;
}
sub get_subtitle_str {
    my ($blobs) = @_;
    if (@$blobs) {
    	$_ = join(' ',@$blobs);
    	s/^\s+//; s/\s+$//;
    	return $_ if length($_);
    }
	return;
}
sub get_year_str {
    my ($blobs) = @_;
    my $year = pop @$blobs;
    return $year if (defined $year && ($year =~ /^\d\d\d\d$/));
	if (defined $year) {push @$blobs, $year};
	return;
}
sub get_rating_str {
    my ($blobs) = @_;
    my $rating = shift @$blobs;
    return $rating if (defined $rating && ($rating =~ /^(ALL|PG|\d+)( [SVLN]+)?$/));
	if (defined $rating) {unshift @$blobs, $rating};
	return;
}
sub get_desc_str {
    $_ = shift;
    s/\n/ /g;
    s/&\#160;/ /g;
	return undef if not defined;
	s/^\s+//; s/\s+$//;
	s/  +/ /g;
	return undef if !length($_);
    return decode_entities($_);
}
sub get_content {
  my (@l) = @_;
  while (@l) {
    my $e = shift @l;
    return $e if !ref($e);
  }
  return undef;
}

sub navigate {
  my ($elem,@dir) = @_;

  if (!@dir) {
    return $elem->content_list();
  } else {
    my $d = shift @dir;
    my $e = $elem->$d();
    if (defined($e)) {
      return navigate($e,@dir);
    } else {
      return undef;
    }
  }
}

# get channel listing
sub get_channels {
    my $bar = new XMLTV::ProgressBar('getting list of channels', 1)
      if not $opt_quiet;
    my %channels;

	# we're only ripping from a single channel
	
	my $channel_id = "etv.co.za";
	$_ = "e-TV";
	$channels{$channel_id}=$_;
	push @ch_all, { 'display-name' => [ [ $_, $LANG ] ],
			'id' => $channel_id };

    die "no channels could be found" if not keys %channels;
    update $bar if not $opt_quiet;
    $bar->finish() if not $opt_quiet;
    return %channels;
}

# Bump a YYYYMMDD date by one.
sub nextday {
    my $d = shift;
    my $p = parse_date($d);
    my $n = DateCalc($p, '+ 1 day');
    return UnixDate($n, '%Q');
}

sub cached_get {
	my $url = shift;

	my $home = $ENV{HOME} || 
               #$ENV{HOMEDRIVE} . $ENV{HOMEPATH} ||
               ".";
               
	my $cachepath = $ENV{CACHE_PATH} || "$home/.xmltv/cache";

	if (not -d($cachepath)) {
		if (not -e($cachepath)) {
			mkdir($cachepath);
		} else {
			die "$cachepath expected to be a directory";
		}
    }
	
	my $cachefile = $url;
	$cachefile =~ s/\:/_/g;
	$cachefile =~ s/\//_/g;
	$cachefile =~ s/\?/_/g;
	$cachefile = "$cachepath/$cachefile.txt";
	
	# if the cache file doesn't exist or it's older than the allowed cache age
	if ((!-f($cachefile)) || ((-M($cachefile) > $opt_cacheage))) {
		my $result = LWP::Simple::getstore($url,$cachefile);
		return undef if !HTTP::Status::is_success($result);
		$XMLTV::Get_nice::Delay = 5;
	} else {
		$XMLTV::Get_nice::Delay = 0;	
	}

	if (-f($cachefile))	
	{
		local(*INPUT, $/);
        open (INPUT, $cachefile)     || die "can't open $cachefile: $!";
		my $data = <INPUT>;
		return $data;
	}
	
	return undef;
}
