#!/usr/bin/perl -w

=pod

=head1 NAME

tv_grab_za_sabc - Grab TV listings for South Africa, from sabc.co.za.

=head1 SYNOPSIS

tv_grab_za_sabc --help

tv_grab_za_sabc [--config-file FILE] --configure [--gui OPTION]

tv_grab_za_sabc [--config-file FILE] [--output FILE] [--days N]
           [--offset N] [--quiet] [--cacheage N]

tv_grab_za_sabc --list-channels

=head1 DESCRIPTION

Output TV listings for several channels available in South Africa.
The data comes from www.sabc.co.za which is the primary broadcasting
company in the county.  The grabber relies on parsing HTML so it might 
stop working at any time.

First run B<tv_grab_za_sabc --configure> to choose, which channels you want
to download. Then running B<tv_grab_za_sabc> with no arguments will output
listings in XML format to standard output.

B<--configure> Prompt for which channels,
and write the configuration file.

B<--config-file FILE> Set the name of the configuration file, the
default is B<~/.xmltv/tv_grab_za_sabc.conf>.  This is the file written by
B<--configure> and read when grabbing.

B<--gui OPTION> Use this option to enable a graphical interface to be used.
OPTION may be 'Tk', or left blank for the best available choice.
Additional allowed values of OPTION are 'Term' for normal terminal output
(default) and 'TermNoProgressBar' to disable the use of XMLTV::ProgressBar.

B<--output FILE> write to FILE rather than standard output.

B<--days N> grab N days.  The default is ten.

B<--offset N> start N days in the future.  The default is to start
from today.

B<--cacheage N> will try and cache downloads, and reuse them if the file is
younger than N days old.  The default is to cache downloads for 1 day.

B<--quiet> suppress the progress messages normally written to standard
error.

B<--list-channels> write output giving <channel> elements for every
channel available (ignoring the config file), but no programmes.

B<--help> print a help message and exit.

=head1 SEE ALSO

L<xmltv(5)>.

=head1 AUTHOR

Norman Rasmussen, norman@rasmussen.org.  
Based on tv_grab_fi by Matti Airas, mairas@iki.fi.  
tv_grab_fi originally based on tv_grab_sn by Stefan G:orling.

=head1 BUGS

The channels are identified by short names rather than the RFC2838 form
recommended by the XMLTV DTD.  The last programme for each channel
does not get a stop date.

=cut

######################################################################
# initializations

use strict;
use XMLTV::Version '$Id: tv_grab_za_sabc,v 1.01 2004/12/29 18:41:39 normanr Exp $ ';
use Getopt::Long;
use Date::Manip;
use HTML::TreeBuilder;
use HTML::Entities; # parse entities
use IO::File;

use XMLTV;
use XMLTV::Memoize;
use XMLTV::ProgressBar;
use XMLTV::Ask;
use XMLTV::Config_file;
use XMLTV::Get_nice;
use LWP::Simple qw($ua);
use XMLTV::Mode;
use XMLTV::Date;
use XMLTV::Usage <<END
$0: get South African television listings from www.sabc.co.za in XMLTV format
To configure: $0 --configure [--config-file FILE]
To grab listings: $0 [--config-file FILE] [--output FILE] [--days N]
        [--offset N] [--quiet] [--cacheage N]
To list channels: $0 --list-channels
END
  ;

# Attributes of the root element in output.
my $HEAD = { 'source-info-url' => 'http://www.sabc.co.za/',
	     'source-data-url'     => 'http://www.sabc.co.za/portal/site/corporate/menuitem.11c2512d562fd7e48891f2e75401aeb9/',
	     'generator-info-name' => 'XMLTV',
	     'generator-info-url'  => 'http://membled.com/work/apps/xmltv/',
	   };

# default language
my $LANG="en-ZA";

# Global channel data.
our @ch_all;
our %ch_ids;

######################################################################
# get options

# Get options, including undocumented --cache option.
XMLTV::Memoize::check_argv('XMLTV::Get_nice::get_nice_aux');
my ($opt_days, $opt_offset, $opt_help, $opt_output, $opt_cacheage,
    $opt_configure, $opt_config_file, $opt_gui,
    $opt_quiet, $opt_list_channels);
$opt_days  = 10; # default
$opt_offset = 0; # default
$opt_cacheage = 1; # default
$opt_quiet  = 0; # default
GetOptions('days=i'    => \$opt_days,
	   'offset=i'      => \$opt_offset,
	   'cacheage=i'    => \$opt_cacheage,
	   'help'          => \$opt_help,
	   'configure'     => \$opt_configure,
	   'config-file=s' => \$opt_config_file,
       'gui:s'         => \$opt_gui,
	   'output=s'      => \$opt_output,
	   'quiet'         => \$opt_quiet,
	   'list-channels' => \$opt_list_channels,
	  )
  or usage(0);
die 'number of days must not be negative'
  if (defined $opt_days && $opt_days < 0);
usage(1) if $opt_help;

XMLTV::Ask::init($opt_gui);

my $mode = XMLTV::Mode::mode('grab', # default
			     $opt_configure => 'configure',
			     $opt_list_channels => 'list-channels',
			    );

# File that stores which channels to download.
my $config_file
  = XMLTV::Config_file::filename($opt_config_file, 'tv_grab_za_sabc', $opt_quiet);

my @config_lines; # used only in grab mode
if ($mode eq 'configure') {
    XMLTV::Config_file::check_no_overwrite($config_file);
}
elsif ($mode eq 'grab') {
    @config_lines = XMLTV::Config_file::read_lines($config_file);
}
elsif ($mode eq 'list-channels') {
    # Config file not used.
}
else { die }

$XMLTV::Get_nice::get = \&cached_get;

# Whatever we are doing, we need the channels data.
my %channels = get_channels(); # sets @ch_all
my @channels;

######################################################################
# write configuration

if ($mode eq 'configure') {
    open(CONF, ">$config_file") or die "cannot write to $config_file: $!";

    # Ask about each channel.
    my @chs = sort {join('.', reverse split(/\./, $a)) cmp join('.', reverse split(/\./, $b))} keys %channels;
    my @names = map { $channels{$_} } @chs;
    my @qs = map { "add channel $_?" } @names;
    my @want = ask_many_boolean(1, @qs);
    foreach (@chs) {
	my $w = shift @want;
	warn("cannot read input, stopping channel questions"), last
	  if not defined $w;
	# No need to print to user - XMLTV::Ask is verbose enough.

	# Print a config line, but comment it out if channel not wanted.
	print CONF '#' if not $w;
	my $name = shift @names;
	print CONF "channel $_ $name\n";
	# TODO don't store display-name in config file.
    }

    close CONF or warn "cannot close $config_file: $!";
    say("Finished configuration.");

    exit();
}

# Not configuration, we must be writing something, either full
# listings or just channels.
#
die if $mode ne 'grab' and $mode ne 'list-channels';

# Options to be used for XMLTV::Writer.
my %w_args;
if (defined $opt_output) {
    my $fh = new IO::File(">$opt_output");
    die "cannot write to $opt_output: $!" if not defined $fh;
    $w_args{OUTPUT} = $fh;
}
#$w_args{encoding} = 'UTF-8';
$w_args{encoding} = 'ISO-8859-1';
my $writer = new XMLTV::Writer(%w_args);
$writer->start($HEAD);

if ($mode eq 'list-channels') {
    # Write channels mode.
    $writer->write_channel($_) foreach @ch_all;
    $writer->end();
    exit();
}

######################################################################
# We are producing full listings.
die if $mode ne 'grab';

# Read configuration.
my $line_num = 1;
foreach (@config_lines) {
    ++ $line_num;
    next if not defined;
    if (/^channel:?\s+(\S+)\s+([^\#]+)/) {
		my $ch_did = $1;
		my $ch_name = $2;
		$ch_name =~ s/\s*$//;
		push @channels, $ch_did;
		$channels{$ch_did} = $ch_name;
    }
    else {
		warn "$config_file:$line_num: bad line\n";
    }
}

######################################################################
# begin main program

# Assume the listings source uses CAT (see BUGS above).
my $now = DateCalc(parse_date('now'), "$opt_offset days");
$opt_days -= 1;
my $then = DateCalc($now, "$opt_days days");
die "No channels specified, run me with --configure\n"
  if not keys %channels;
my @to_get;

# the order in which we fetch the channels matters
foreach my $ch_did (@channels) {
    my $ch_name=$channels{$ch_did};
    my $ch_xid=$ch_did;
    $writer->write_channel({ id => $ch_xid,
			     'display-name' => [ [ $ch_name ] ] });
	push @to_get, [ [ $now, $then ] , $ch_xid, $ch_ids{$ch_did} ];
}

# This progress bar is for both downloading and parsing.  Maybe
# they could be separate stages.
#
my $bar = new XMLTV::ProgressBar('getting listings', scalar @to_get)
  if not $opt_quiet;
foreach (@to_get) {
    foreach (process_table($_->[0], $_->[1], $_->[2])) {
		$writer->write_programme($_);
    }
    update $bar if not $opt_quiet;
}
$bar->finish() if not $opt_quiet;
$writer->end();

######################################################################
# subroutine definitions

# Use Log::TraceMessages if installed.
BEGIN {
    eval { require Log::TraceMessages };
    if ($@) {
	*t = sub {};
	*d = sub { '' };
    }
    else {
	*t = \&Log::TraceMessages::t;
	*d = \&Log::TraceMessages::d;
	Log::TraceMessages::check_argv();
    }
}

my $warned_bad_chars;
sub tidy( $ ) {
    for (my $tmp = shift) {
	tr/\t\205/ /d;
	s/&nbsp;/ /g;
	if (s/([^\012\015\040-\176\240-\377]+)//g) {
	    warn "removing bad characters: '$1'"
	      unless $warned_bad_chars++;
	}
	return $_;
    }
}

####
# process_table: fetch a URL and process it
#
# arguments:
#    Date::Manip object giving the day to grab
#    xmltv id of channel
#    sabc id of channel
#
# returns: list of programme hashes to write
#
sub process_table {
    my ($date, $ch_xmltv_id, $ch_sabc_id) = @_;
    
    my $startdate = UnixDate(@$date[0], 'xday1=%d&xmonth1=%m&xyear1=%Y');
    my $enddate = UnixDate(@$date[1], 'xday2=%d&xmonth2=%m&xyear2=%Y');
    
    my $url = "http://www.sabc.co.za/portal/site/corporate/menuitem.11c2512d562fd7e48891f2e75401aeb9/?sch=yes&$startdate&$enddate&channel=$ch_sabc_id";
    t "getting URL: $url";
    my $data=tidy(get_nice($url));
    if (not defined $data) {
		die "could not fetch $url, aborting\n";
    }
    local $SIG{__WARN__} = sub {
		warn "$url: $_[0]";
    };

    # parse the page to a document object
    my $tree = HTML::TreeBuilder->new();
    $tree->parse($data);
    my @program_data = get_program_data($tree);

    my @r;
    while (@program_data) {
		my $cur = shift @program_data;
		my $next = shift @program_data;
		unshift @program_data,$next if $next;
		push @r, make_programme_hash($date, $ch_xmltv_id, $ch_sabc_id, $cur, $next);
    }
    return @r;
}

sub make_programme_hash {
    my ($date, $ch_xmltv_id, $ch_sabc_id, $cur, $next) = @_;
	$date = $cur->{date};
    my %prog;

    $prog{channel}=$ch_xmltv_id;
    $prog{title}=[ [ $cur->{title}, $LANG ] ];

    my $cur_time = $cur->{time};
    t 'raw time for programme: ' . d $cur_time;
    my $start=parse_date("$date $cur_time");
    t 'parse_date() returned: ' . d $start;
    $prog{start}=UnixDate($start, '%q') . " +0200";
    t 'set programme start time to: ' . d $prog{start};

    my $next_time = $next ? $next->{time} : undef;
    if (defined $next_time) {
		t '$cur_time=' . d $cur_time;
		t '$next_time=' . d $next_time;
		my $stop_date;
		if ($next_time lt $cur_time) {
		    # Must span midnight.  (Don't worry about start being
		    # summer time and stop being winter: we assume the site is
		    # sane enough to put them both in the same timezone and
		    # avoid looking like stop < start.)
		    #
		    t '$next_time appears sooner, must be next day';
		    $stop_date = nextday($date);
		}
		else {
		    $stop_date = $date;
		}
		t '$stop_date set to: ' . d $stop_date;
		my $stop = parse_date("$stop_date $next_time");
		t 'stop time in CAT: ' . d $stop;
		$prog{stop}=UnixDate($stop, '%q') . " +0200";
    }	

    # FIXME: parse description field further
    $prog{desc}=[ [ $cur->{desc}, $LANG ] ] if defined $cur->{desc};

    return \%prog;
}
sub bump_start_day {
    my ($cur,$next) = @_;
    if (!defined($next)) {
	return undef;
    }
    my $start = UnixDate($cur->{time},'%H:%M');
    my $stop = UnixDate($next->{time},'%H:%M');
    if (Date_Cmp($start,$stop)>0) {
	return 1;
    } else {
	return 0;
    }
}

# program data is split as follows:
# - td with class=kanava-klo is the time
# - its sibling td with class=kanava-ohj(-nyt)? (two to the right)
#   is the program
# - second td on the next row is the description
sub get_program_data {
    my $tree = shift;
    t "get_program_data() ENTRY for tree: $tree";
    my @data;

    my @date_elems = get_date_elems($tree);
    t 'date elements: ' . d \@date_elems . ' of ' . scalar @date_elems . ' elements';

    # Subroutines to call on each element.
    my %keys = (time => \&get_time_str,
		title => \&get_name_str,
		desc => \&get_desc_str,
	       );
    # Actually time and title are required, but we don't check that.
    foreach my $elem (@date_elems) {
		my $date = get_content((($elem->content_list())[0])->content_list());
		$date =~ s/Date +: +//;
		t 'doing elem: ' . d $date;
		
	    my @title_elems = get_title_elems($elem);
	    t 'title elements: ' . d \@title_elems . ' of ' . scalar @title_elems . ' elements';

    	foreach my $elem (@title_elems) {
			my %h;
		   	$h{date} = $date;
			foreach my $k (keys %keys) {
			    my $sub = $keys{$k};
			    my $v = $sub->($elem);
			    if (defined $v) {
					t "got a result from sub for $k: $v";
					$h{$k} = $v;
			    }
			}
			t 'after running all subs, got data: ' . d \%h;
			push @data, \%h;
    	}
    }
    t 'get_program_data() RETURNING ' . d \@data;
    return @data;
}
sub get_date_elems {
    my ($tree) = @_;
    my @date_elems = $tree->look_down
      ("_tag"=>"td", 
       "colspan"=>"5");
    return @date_elems;
}
sub get_title_elems {
    my ($tree) = @_;
    my @title_elems = $tree->parent->right->look_down
      ("_tag"=>"span");
    return @title_elems;
}
sub get_time_str {
    my ($title_elem) = @_;
    my $time = $title_elem->left;
    $time = UnixDate(parse_date($time), '%R');
    return $time;
}
sub get_name_str {
    my ($title_elem) = @_;
    return get_content($title_elem->content_list());
}
sub get_desc_str {
    my ($title_elem) = @_;
    $_ = $title_elem->attr('title');
    return undef if $_ eq 'No Description';
    s/\s+$//;
	return $_ if length($_);
	return;
}
sub get_content {
  my (@l) = @_;
  while (@l) {
    my $e = shift @l;
    return $e if !ref($e);
  }
  return undef;
}

sub navigate {
  my ($elem,@dir) = @_;

  if (!@dir) {
    return $elem->content_list();
  } else {
    my $d = shift @dir;
    my $e = $elem->$d();
    if (defined($e)) {
      return navigate($e,@dir);
    } else {
      return undef;
    }
  }
}

# get channel listing
sub get_channels {
    my $bar = new XMLTV::ProgressBar('getting list of channels', 1)
      if not $opt_quiet;
    my %channels;
    my $url="http://www.sabc.co.za/portal/site/corporate/menuitem.11c2512d562fd7e48891f2e75401aeb9/";
    my $local_data=get_nice($url);
    die "could not get channel listing $url, aborting\n"
      if not defined $local_data;

    # FIXME commonize this
    local $SIG{__WARN__} = sub {
	warn "$url: $_[0]";
    };
    local $SIG{__DIE__} = sub {
	die "$url: $_[0]";
    };
    
    my $tree = HTML::TreeBuilder->new();
    $tree->parse($local_data);

    # all channel elements are option tags within the select named channel

    my @select_elems = $tree->look_down(_tag => 'select',
					name => 'channel');
    my @ch_op_elems = map { $_->look_down(_tag => 'option') } @select_elems;
    foreach my $elem (@ch_op_elems) {
		my $channel_id = $elem->attr('value');
	    my @children=$elem->content_list;
	    if (scalar(@children) != 1 || ref($children[0])) {
			warn "Illegal channel name";
			next;
	    }
	    if (!($channel_id =~ /^\d+$/)) { next };
	    for ($children[0]) {
			s/^\s+//; s/\s+$//;
			my $channel_name=lc $_.".co.za";
			$channel_name =~ s/ //;
			t sprintf('%3d', $channel_id).":".$channel_name;
			$channels{$channel_name}=$_;
			$ch_ids{$channel_name}=$channel_id;
			push @ch_all, { 'display-name' => [ [ $_, $LANG ] ],
							'id' => $channel_name };
	    }
	}
    die "no channels could be found" if not keys %channels;
    update $bar if not $opt_quiet;
    $bar->finish() if not $opt_quiet;
    return %channels;
}

# Bump a YYYYMMDD date by one.
sub nextday {
    my $d = shift;
    my $p = parse_date($d);
    my $n = DateCalc($p, '+ 1 day');
    return UnixDate($n, '%Q');
}

sub cached_get {
	my $url = shift;

	my $home = $ENV{HOME} || 
               #$ENV{HOMEDRIVE} . $ENV{HOMEPATH} ||
               ".";
               
	my $cachepath = $ENV{CACHE_PATH} || "$home/.xmltv/cache";

	if (not -d($cachepath)) {
		if (not -e($cachepath)) {
			mkdir($cachepath);
		} else {
			die "$cachepath expected to be a directory";
		}
    }
	
	my $cachefile = $url;
	$cachefile =~ s/\:/_/g;
	$cachefile =~ s/\//_/g;
	$cachefile =~ s/\?/_/g;
	$cachefile = "$cachepath/$cachefile.txt";
	
	# if the cache file doesn't exist or it's older than the allowed cache age
	if ((!-f($cachefile)) || ((-M($cachefile) > $opt_cacheage))) {
		my $result = LWP::Simple::getstore($url,$cachefile);
		return undef if !HTTP::Status::is_success($result);
		$XMLTV::Get_nice::Delay = 5;
	} else {
		$XMLTV::Get_nice::Delay = 0;	
	}

	if (-f($cachefile))	
	{
		local(*INPUT, $/);
        open (INPUT, $cachefile)     || die "can't open $cachefile: $!";
		my $data = <INPUT>;
		return $data;
	}
	
	return undef;
}
